# Plot (in letterbox and square forms) a by-hour time series summary.

# Input data of form:
#beat bytes/h hits/h
#00 804345.1 46.125
#01 828962.1 46.25
#02 829160.0 44.125
#03 895587.4 45.5
#04 786173.6 42.0
#05 995659.6 49.375
#06 874302.25 49.75
#07 834344.0 47.125
#08 1058068.5 52.125
#09 944422.75 51.625
#10 983488.4 51.375
#11 995267.25 54.0
#12 960692.9 57.375
#13 868717.75 50.625
#14 919967.0 53.0
#...

# Input filename supplied as:
#     gnuplot -e "infilename='in.dat'"
if (!exists("infilename")) infilename='bhs-in.dat'
# Output filename prefix supplied as:
#     gnuplot -e "outfilenameprefix='outprefix'"
if (!exists("outfilenameprefix")) outfilenameprefix='bhs-out'

# Letterbox 800x200 PNG.
outputlb=outfilenameprefix . '.lb.png'
set terminal png small size 800,200
set output outputlb
#print "Saving letterbox form to " . outputlb
# x data is just (cyclic) labels.
set key box opaque
set xdata
set xtics 1
set grid
unset border
set noytics
#set y2tics
set xrange noextend
#set format y "MB/h %.1f"
#set format y2 "hits/h %g"
plot infilename \
    using (column(0)/24):($2/1000000) title columnheader with points, \
 "" using (column(0)/24):3 title columnheader with points axes x1y2

# Square 1600x1600 PNG.
outputsq=outfilenameprefix . '.sq.png'
set terminal png large size 1600,1600
set output outputsq
#print "Saving square coverart form to " . outputsq
# x data is just (cyclic) labels.
set key opaque
set xdata
set xtics 1
set grid
unset border
set ytics
set y2tics
set xrange noextend
set format y "MB/h %.1f"
set format y2 "hits/h %g"
plot infilename \
    using (column(0)/24):($2/1000000) title columnheader smooth bezier lw 8, \
 "" using (column(0)/24):3 title columnheader smooth bezier axes x1y2 lw 10