# Plot yearly carbon footprint.
# See http://gnuplot.sourceforge.net/demo/finance.html
set terminal png size 320,240
set output "out/yearly/16WWYearlyEnergyCarbonFootprint.png.tmp"
set title "16WW Carbon Footprint kgCO2e/y"
set grid
set lmargin 6
set rmargin 2
set tmargin 2
set bmargin 3
set xrange [2006:]
set xtics rotate
#set xtics 2
# Use more advanced value in column 9 where available, else use 7 (static).
plot "data/16WWYearlyEnergyCarbonFootprint.dat" \
     using 1:(valid(9)?$9:$7) notitle with lines

# Generate SVG alongside.
set terminal svg size 320,240 background rgb 'white'
set output "out/yearly/16WWYearlyEnergyCarbonFootprint.svg.tmp"
replot

# Generate slightly more formal (journal-ready) PDF alongside.
set terminal pdfcairo size 8cm,6cm background rgb 'white'
# Omit title from journal/formal image.
unset title
set lmargin
set rmargin
set tmargin
set bmargin
set xlabel "Year"
set ylabel "Utility energy CO2e (kg)"
set output "out/yearly/16WWYearlyEnergyCarbonFootprint.pdf.tmp"
plot "data/16WWYearlyEnergyCarbonFootprint.dat" \
     using 1:(valid(9)?$9:$7) notitle with lines